Merge pull request #22790 from hvitved/unified/type-inference-param-ex

Unified: Use `ParameterEx` in type inference

Author: hvitved

unified/extractor/ast_types.yml

@@ -79,6 +79,7 @@ supertypes:
     fields:
       parameter*: parameter
       body?: block
+      return_type?: expr
   # A member is anything that can appear in the body of a class-like declaration
   member:
     subtypes:

unified/ql/lib/codeql/unified/internal/Ast.qll

@@ -369,6 +369,9 @@ module Unified {
 
     /** Gets the node corresponding to the field `parameter`. */
     F::Parameter getAParameter() { none() }
+
+    /** Gets the node corresponding to the field `return_type`. */
+    F::Expr getReturnType() { none() }
   }
 
   /** A class representing `catch_clause` nodes. */
@@ -721,7 +724,9 @@ module Unified {
     final override F::Parameter getAParameter() { result = this.getParameter(_) }
 
     /** Gets the node corresponding to the field `return_type`. */
-    final F::Expr getReturnType() { unified_function_declaration_return_type(this, result) }
+    final override F::Expr getReturnType() {
+      unified_function_declaration_return_type(this, result)
+    }
 
     /** Gets the node corresponding to the field `type_constraint`. */
     final F::TypeConstraint getTypeConstraint(int i) {
@@ -782,7 +787,7 @@ module Unified {
     final override F::Parameter getAParameter() { result = this.getParameter(_) }
 
     /** Gets the node corresponding to the field `return_type`. */
-    final F::Expr getReturnType() { unified_function_expr_return_type(this, result) }
+    final override F::Expr getReturnType() { unified_function_expr_return_type(this, result) }
 
     /** Gets a field or child node of this node. */
     final override F::AstNode getAFieldOrChild() {

unified/ql/lib/codeql/unified/internal/AstPlugin.qll

@@ -1,4 +1,4 @@
-overlay[local]
+overlay[local?]
 module;
 
 private import unified
@@ -23,10 +23,26 @@ class AstPlugin extends Unit {
 
   /**
    * Holds if the default constructor `cd` needs a parameter at index `i` with
-   * the given name. `i = 0` is reserved for the implicit receiver parameter.
+   * the given name. `hasDefault` indicates whether the parameter has a default
+   * value.
+   *
+   * `i = 0` is reserved for the implicit receiver parameter.
    */
   bindingset[cd]
-  predicate defaultConstructorParameter(ConstructorDeclaration cd, int i, string name) { none() }
+  predicate defaultConstructorParameter(
+    ConstructorDeclaration cd, int i, string name, boolean hasDefault
+  ) {
+    none()
+  }
+
+  /**
+   * Holds if the type of the `i`th parameter of the default constructor `cd`
+   * is `type`.
+   */
+  bindingset[cd]
+  predicate defaultConstructorParameterType(ConstructorDeclaration cd, int i, AstNode type) {
+    none()
+  }
 }
 
 bindingset[f]
@@ -50,6 +66,13 @@ string getVariableDeclarationKeyword(VariableDeclaration decl) {
 }
 
 bindingset[cd]
-predicate defaultConstructorParameter(ConstructorDeclaration cd, int i, string name) {
-  any(AstPlugin p).defaultConstructorParameter(cd, i, name)
+predicate defaultConstructorParameter(
+  ConstructorDeclaration cd, int i, string name, boolean hasDefault
+) {
+  any(AstPlugin p).defaultConstructorParameter(cd, i, name, hasDefault)
+}
+
+bindingset[cd]
+predicate defaultConstructorParameterType(ConstructorDeclaration cd, int i, AstNode type) {
+  any(AstPlugin p).defaultConstructorParameterType(cd, i, type)
 }

unified/ql/lib/codeql/unified/internal/AstPluginSwift.qll

@@ -1,9 +1,36 @@
-overlay[local]
+overlay[local?]
 module;
 
 private import unified
 private import AstPlugin
 
+private predicate structHasParameterForField(
+  ConstructorDeclaration cd, VariableDeclaration decl, int i, string name, boolean hasDefault
+) {
+  exists(ClassLikeDeclaration struct |
+    struct.hasModifier("struct") and
+    cd = struct.getAMember() and
+    decl = struct.getMember(i) and
+    not decl.hasModifier("static") and
+    name = decl.getPattern().(Identifier).getValue()
+  |
+    // if `decl` has an initializer or `Optional` type then the parameter has a default value
+    decl.hasModifier("var") and
+    if
+      exists(decl.getValue())
+      or
+      // we could make this more precise using static name binding, but for now we
+      // use a simpler approach to avoid the dependency on static name binding
+      decl.getType().(GenericTypeExpr).getBase().(Identifier).getValue() = "Optional"
+    then hasDefault = true
+    else hasDefault = false
+    or
+    decl.hasModifier("let") and
+    not exists(decl.getValue()) and
+    hasDefault = false
+  )
+}
+
 private class AstPluginSwift extends AstPlugin {
   bindingset[f]
   override string getFunctionDeclarationKeyword(FunctionDeclaration f) {
@@ -27,25 +54,19 @@ private class AstPluginSwift extends AstPlugin {
   }
 
   bindingset[cd]
-  override predicate defaultConstructorParameter(ConstructorDeclaration cd, int i, string name) {
-    exists(ClassLikeDeclaration cls |
-      cd = cls.getAMember() and
-      cls.hasModifier("struct") and
-      name =
-        rank[i](VariableDeclaration decl, int j, string s |
-          decl = cls.getMember(j) and
-          not decl.hasModifier("static") and
-          (
-            // if `decl` has an initializer then this parameter has that initializer as a default value
-            decl.hasModifier("var")
-            or
-            decl.hasModifier("let") and
-            not exists(decl.getValue())
-          ) and
-          s = decl.getPattern().(Identifier).getValue()
-        |
-          s order by j
-        )
+  override predicate defaultConstructorParameter(
+    ConstructorDeclaration cd, int i, string name, boolean hasDefault
+  ) {
+    name = rank[i](int j, string s | structHasParameterForField(cd, _, j, s, _) | s order by j) and
+    structHasParameterForField(cd, _, _, name, hasDefault)
+  }
+
+  bindingset[cd]
+  override predicate defaultConstructorParameterType(ConstructorDeclaration cd, int i, AstNode type) {
+    exists(VariableDeclaration decl, string name |
+      this.defaultConstructorParameter(cd, i, name, _) and
+      structHasParameterForField(cd, decl, _, name, _) and
+      type = decl.getType()
     )
   }
 }

unified/ql/lib/codeql/unified/internal/ParameterEx.qll

@@ -11,9 +11,9 @@ private newtype TParameterEx =
   TImplicitReceiverParameter(Callable c) {
     exists(LocalVariable v | v.isImplicitReceiverParameter(c))
   } or
-  TDefaultConstructorParameter(ConstructorDeclaration cd, int i, string name) {
+  TDefaultConstructorParameter(ConstructorDeclaration cd, int i, string name, boolean hasDefault) {
     cd.hasModifier("generated") and
-    defaultConstructorParameter(cd, i, name)
+    defaultConstructorParameter(cd, i, name, hasDefault)
   }
 
 final class ParameterEx = ParameterExImpl;
@@ -42,7 +42,7 @@ abstract private class ParameterExImpl extends TParameterEx {
    * constructor `cd` with name `name`.
    */
   predicate isDefaultConstructorParameter(ConstructorDeclaration cd, int i, string name) {
-    this = TDefaultConstructorParameter(cd, i, name)
+    this = TDefaultConstructorParameter(cd, i, name, _)
   }
 
   /** Gets the callable that this parameter belongs to. */
@@ -60,6 +60,12 @@ abstract private class ParameterExImpl extends TParameterEx {
     this.isDefaultConstructorParameter(result, _, _)
   }
 
+  /** Holds if this parameter has a default value. */
+  abstract predicate hasDefault();
+
+  /** Gets the type declaration of this parameter, if any. */
+  abstract AstNode getType();
+
   /** Gets a textual representation of this parameter. */
   abstract string toString();
 
@@ -72,6 +78,10 @@ private class AstParameterEx extends ParameterExImpl, TAstParameter {
 
   AstParameterEx() { this = TAstParameter(p) }
 
+  override predicate hasDefault() { exists(p.getDefault()) }
+
+  override AstNode getType() { result = p.getType() }
+
   override string toString() { result = p.toString() }
 
   override Location getLocation() { result = p.getLocation() }
@@ -82,6 +92,10 @@ private class ImplicitReceiverParameterEx extends ParameterExImpl, TImplicitRece
 
   ImplicitReceiverParameterEx() { this = TImplicitReceiverParameter(c) }
 
+  override predicate hasDefault() { none() }
+
+  override AstNode getType() { none() }
+
   override string toString() {
     exists(LocalVariable v |
       v.isImplicitReceiverParameter(c) and
@@ -96,8 +110,13 @@ private class DefaultConstructorParameterEx extends ParameterExImpl, TDefaultCon
   ConstructorDeclaration cd;
   int i;
   string name;
+  boolean hasDefault;
+
+  DefaultConstructorParameterEx() { this = TDefaultConstructorParameter(cd, i, name, hasDefault) }
+
+  override AstNode getType() { defaultConstructorParameterType(cd, i, result) }
 
-  DefaultConstructorParameterEx() { this = TDefaultConstructorParameter(cd, i, name) }
+  override predicate hasDefault() { hasDefault = true }
 
   override string toString() { result = name + " [" + cd.getName() + " default constructor]" }
 

unified/ql/lib/codeql/unified/internal/typeinference/Type.qll

@@ -1,4 +1,6 @@
 /** Provides classes representing types without type arguments. */
+overlay[local?]
+module;
 
 import unified // reexport in order to shadow e.g. the `TypeParameter` class
 private import unified as Unified